From e8f20000536dd49e64fdb125ebd4babb03c07ce1 Mon Sep 17 00:00:00 2001
From: sid <sid@sid.ovh>
Date: Tue, 19 May 2026 13:13:02 +0200
Subject: [PATCH] add nerdlog package

---
 pkgs/default.nix         |  1 +
 pkgs/nerdlog/default.nix | 83 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)
 create mode 100644 pkgs/nerdlog/default.nix

diff --git a/pkgs/default.nix b/pkgs/default.nix
index 28c1f0b..899a133 100644
--- a/pkgs/default.nix
+++ b/pkgs/default.nix
@@ -15,6 +15,7 @@
   jirafeau-cli = pkgs.callPackage ./jirafeau-cli { };
   kicad-mcp = pkgs.callPackage ./kicad-mcp { };
   mcpo = pkgs.callPackage ./mcpo { };
+  nerdlog = pkgs.callPackage ./nerdlog { };
   pass2bw = pkgs.callPackage ./pass2bw { };
   pyman = pkgs.callPackage ./pyman { };
   quicknote = pkgs.callPackage ./quicknote { };
diff --git a/pkgs/nerdlog/default.nix b/pkgs/nerdlog/default.nix
new file mode 100644
index 0000000..b1b59f0
--- /dev/null
+++ b/pkgs/nerdlog/default.nix
@@ -0,0 +1,83 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  stdenv,
+  darwin,
+  xorg,
+  pkg-config,
+  wayland,
+  libGL,
+  libxkbcommon,
+  makeWrapper,
+}:
+
+buildGoModule rec {
+  pname = "nerdlog";
+  version = "1.10.0";
+
+  src = fetchFromGitHub {
+    owner = "dimonomid";
+    repo = "nerdlog";
+    rev = "v${version}";
+    hash = "sha256-XlzWNeyd+Ar4ArFcN1wkQ0aod6ckAiIb12odK7cf4+s=";
+  };
+
+  vendorHash = "sha256-hvv0dsE1yz85VLaBOE7RWbux8L8kVTihcA1HyyHRYAM=";
+
+  subPackages = [
+    "cmd/nerdlog"
+    "cmd/generate_syslog"
+  ];
+
+  doCheck = false;
+
+  nativeBuildInputs = [
+    pkg-config
+    makeWrapper
+  ];
+
+  buildInputs =
+    lib.optionals stdenv.isDarwin [
+      darwin.apple_sdk.frameworks.Cocoa
+    ]
+    ++ lib.optionals stdenv.isLinux [
+      xorg.libX11
+      xorg.libXext
+      xorg.libXfixes
+      wayland
+      libGL
+      libxkbcommon
+    ];
+
+  postInstall = lib.optionalString stdenv.isLinux ''
+    wrapProgram $out/bin/nerdlog \
+      --prefix LD_LIBRARY_PATH : ${
+        lib.makeLibraryPath [
+          xorg.libX11
+          xorg.libXext
+          xorg.libXfixes
+          wayland
+          libGL
+          libxkbcommon
+        ]
+      }
+  '';
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X=github.com/dimonomid/nerdlog/version.version=${version}"
+    "-X=github.com/dimonomid/nerdlog/version.commit=${src.rev}"
+    "-X=github.com/dimonomid/nerdlog/version.date=1970-01-01T00:00:00Z"
+    "-X=github.com/dimonomid/nerdlog/version.builtBy=goreleaser"
+  ];
+
+  meta = {
+    description = "Nerdlog: fast, remote-first, multi-host TUI log viewer with timeline histogram and no central server";
+    homepage = "https://github.com/dimonomid/nerdlog";
+    changelog = "https://github.com/dimonomid/nerdlog/blob/${src.rev}/CHANGELOG.md";
+    license = lib.licenses.bsd2;
+    mainProgram = "nerdlog";
+  };
+}
-- 
2.51.2