From 914db962e4eb1b44529e9cb01172f2e6f1294017 Mon Sep 17 00:00:00 2001
From: sid <sid@sid.ovh>
Date: Fri, 17 Apr 2026 17:05:13 +0200
Subject: [PATCH] add tinyfugue

---
 pkgs/default.nix           |  1 +
 pkgs/tinyfugue/default.nix | 61 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)
 create mode 100644 pkgs/tinyfugue/default.nix

diff --git a/pkgs/default.nix b/pkgs/default.nix
index 2cc8b2d..2d87a7a 100644
--- a/pkgs/default.nix
+++ b/pkgs/default.nix
@@ -18,6 +18,7 @@
   quicknote = pkgs.callPackage ./quicknote { };
   synapse_change_display_name = pkgs.callPackage ./synapse_change_display_name { };
   synix-docs = pkgs.callPackage ./synix-docs { };
+  tinyfugue = pkgs.callPackage ./tinyfugue { };
   trelis-gitingest-mcp = pkgs.callPackage ./trelis-gitingest-mcp { };
   tunerstudio = pkgs.callPackage ./tunerstudio { };
 
diff --git a/pkgs/tinyfugue/default.nix b/pkgs/tinyfugue/default.nix
new file mode 100644
index 0000000..f675682
--- /dev/null
+++ b/pkgs/tinyfugue/default.nix
@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  ncurses,
+  openssl,
+  pcre2,
+  zlib,
+
+  lua5_4,
+  python3,
+  icu,
+
+  enableLua ? true,
+  enablePython ? true,
+  enableWidechar ? true,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "tinyfugue";
+  version = "5.2.2";
+
+  src = fetchFromGitHub {
+    owner = "ingwarsw";
+    repo = "tinyfugue";
+    rev = version;
+    hash = "sha256-nHgu0XJ2Nd0JYrs3o/NLZ9gq1D4ubdPyowQLyhOzDDA=";
+  };
+
+  buildInputs = [
+    ncurses
+    openssl
+    pcre2
+    zlib
+  ]
+  ++ lib.optional enableLua lua5_4
+  ++ lib.optional enablePython python3
+  ++ lib.optional enableWidechar icu;
+
+  env.NIX_CFLAGS_COMPILE = "-D_DEFAULT_SOURCE";
+
+  configureFlags = [
+    "--enable-termcap=ncurses"
+  ]
+  ++ lib.optional enableLua "--enable-lua"
+  ++ lib.optional enablePython "--enable-python"
+  ++ lib.optional (!enableWidechar) "--disable-widechar";
+
+  installPhase = ''
+    make install
+  '';
+
+  meta = {
+    description = "TinyFugue - Rebirth";
+    homepage = "https://github.com/ingwarsw/tinyfugue";
+    changelog = "https://github.com/ingwarsw/tinyfugue/blob/${src.rev}/CHANGES";
+    license = lib.licenses.gpl2Only;
+    mainProgram = "tf";
+    platforms = lib.platforms.all;
+  };
+}