{ inputs, ... }:

{
  default = final: prev: {
    lib = prev.lib // inputs.self.lib;
  };

  additions = final: _prev: import ../pkgs { pkgs = final; };

  modifications = final: prev: {
    # https://github.com/NixOS/nixpkgs/issues/335003#issuecomment-2755803376
    kicad = (
      prev.kicad.override {
        stable = true;
      }
    );

    # bemenu is not a valid selector in v1.5.1
    rofi-rbw-wayland = prev.rofi-rbw-wayland.overrideAttrs (oldAttrs: {
      version = "unstable-2026-01-05";
      src = prev.fetchFromGitHub {
        owner = "fdw";
        repo = "rofi-rbw";
        rev = "2cfbbadf7f585bc0163bb84cd6a205a2bceafab4";
        hash = "sha256-2gSZniHv/sT3eR1BThxbO2MqnCIfkaKqvFYoqdOk3xY=";
      };
    });
  };
}
