{
  pkgs,
  lib,
  ...
}:

let
  python = pkgs.python3Packages;

  mcp-log-server = python.buildPythonApplication {
    pname = "mcp-log-server";
    version = "1.0.0";

    src = ./.;

    pyproject = true;
    build-system = [ python.setuptools ];

    propagatedBuildInputs = with python; [
      fastmcp
    ];

    meta.mainProgram = "mcp-log-server";
  };
in
{
  services.journald.remote = {
    enable = true;
    listen = "http";
    port = 19532;
    settings.Remote.SplitMode = "host";
  };

  users.users.sid.extraGroups = [
    "systemd-journal"
    "systemd-journal-remote"
  ];

  systemd.services.mcp-log-server = {
    description = "AI Log Access MCP Server";
    after = [
      "network.target"
      "multi-user.target"
      "systemd-journald.service"
    ];
    wantedBy = [ "multi-user.target" ];

    script = lib.getExe mcp-log-server;

    serviceConfig = {
      User = "root";
      Group = "root";
      Environment = "PYTHONUNBUFFERED=1";
      Restart = "on-failure";
    };
  };
}